architectury-api/common/build.gradle

loom {
    accessWidenerPath = file("src/main/resources/architectury.accessWidener")
}

dependencies {
    // We depend on fabric loader here to use the fabric @Environment annotations
    // Do NOT use other classes from fabric loader
    modImplementation "net.fabricmc:fabric-loader:${rootProject.fabric_loader_version}"
}

architectury {
    common(rootProject.forgeEnabled.toBoolean())
}

afterEvaluate {
    remapJar {
        remapAccessWidener = false
    }
}

configurations {
    dev
}

artifacts {
    dev(jar)
}

publishing {
    publications {
        mavenCommon(MavenPublication) {
            artifactId = rootProject.archivesBaseName
            from components.java
        }
    }

    repositories {
        if (System.getenv("MAVEN_PASS") != null) {
            maven {
                url = "https://deploy.shedaniel.me/"
                credentials {
                    username = "shedaniel"
                    password = System.getenv("MAVEN_PASS")
                }
            }
        }
    }
}