Extras: added publishing tasks to build.gradle.kts

flatlaf-extras/build.gradle.kts

@@ -16,9 +16,123 @@
 
 plugins {
 	`java-library`
+	`maven-publish`
+	id( "com.jfrog.bintray" )
+	id( "com.jfrog.artifactory" )
 }
 
 dependencies {
 	implementation( project( ":flatlaf-core" ) )
 	implementation( "com.formdev:svgSalamander:1.1.2.1" )
 }
+
+tasks {
+	assemble {
+		dependsOn(
+			"sourcesJar",
+			"javadocJar"
+		)
+	}
+
+	javadoc {
+		options {
+			this as StandardJavadocDocletOptions
+			tags = listOf( "uiDefault", "clientProperty" )
+		}
+		isFailOnError = false
+	}
+
+	register( "sourcesJar", Jar::class ) {
+		archiveClassifier.set( "sources" )
+
+		from( sourceSets.main.get().allJava )
+	}
+
+	register( "javadocJar", Jar::class ) {
+		archiveClassifier.set( "javadoc" )
+
+		from( javadoc )
+	}
+}
+
+publishing {
+	publications {
+		create<MavenPublication>( "maven" ) {
+			artifactId = "flatlaf-extras"
+			groupId = "com.formdev"
+
+			from( components["java"] )
+
+			artifact( tasks["sourcesJar"] )
+			artifact( tasks["javadocJar"] )
+
+			pom {
+				name.set( "FlatLaf Extras" )
+				description.set( "Flat Look and Feel Extras" )
+				url.set( "https://github.com/JFormDesigner/FlatLaf" )
+
+				licenses {
+					license {
+						name.set( "The Apache License, Version 2.0" )
+						url.set( "https://www.apache.org/licenses/LICENSE-2.0.txt" )
+					}
+				}
+
+				developers {
+					developer {
+						name.set( "Karl Tauber" )
+						organization.set( "FormDev Software GmbH" )
+						organizationUrl.set( "https://www.formdev.com/" )
+					}
+				}
+
+				scm {
+					url.set( "https://github.com/JFormDesigner/FlatLaf" )
+				}
+			}
+		}
+	}
+}
+
+bintray {
+	user = rootProject.extra["bintray.user"] as String?
+	key = rootProject.extra["bintray.key"] as String?
+
+	setPublications( "maven" )
+
+	with( pkg ) {
+		repo = "flatlaf"
+		name = "flatlaf-extras"
+		setLicenses( "Apache-2.0" )
+		vcsUrl = "https://github.com/JFormDesigner/FlatLaf"
+
+		with( version ) {
+			name = project.version.toString()
+		}
+
+		publish = rootProject.extra["bintray.publish"] as Boolean
+		dryRun = rootProject.extra["bintray.dryRun"] as Boolean
+	}
+}
+
+artifactory {
+	setContextUrl( "https://oss.jfrog.org" )
+
+	publish( closureOf<org.jfrog.gradle.plugin.artifactory.dsl.PublisherConfig> {
+		repository( delegateClosureOf<groovy.lang.GroovyObject> {
+			setProperty( "repoKey", "oss-snapshot-local" )
+			setProperty( "username", rootProject.extra["bintray.user"] as String? )
+			setProperty( "password", rootProject.extra["bintray.key"] as String? )
+		} )
+
+		defaults( delegateClosureOf<groovy.lang.GroovyObject> {
+			invokeMethod( "publications", "maven" )
+			setProperty( "publishArtifacts", true )
+			setProperty( "publishPom", true )
+		} )
+	} )
+
+	resolve( delegateClosureOf<org.jfrog.gradle.plugin.artifactory.dsl.ResolverConfig> {
+		setProperty( "repoKey", "jcenter" )
+	} )
+}